2011年11月21日月曜日

Microsoft VDI用のクライアントセットアップ用スクリプト

Microsoft VDIは、素質はいいのですが、仮想マシンの構成がかなり面倒です。
1日の教育コース「マイクロソフト仮想化ソリューション」では、仮想マシン構成用のスクリプトを紹介していますが、ここにも掲載しておきます。

解説は省略します。

rem SERVERxxは仮想化ホストの名前
set RD-VH=SERVERxx

rem OSのバージョン番号の判定(XPなら5、VistaまたはWindows 7は6)
for /f "usebackq tokens=2 delims=[]"  %%v  in ( `cmd /c ver`) do set VER=%%v
set VER=%VER:~8,1%

rem ファイルとプリンタ共有の許可
if "%VER%" == "5" netsh firewall set service FILEANDPRINT enable
if "%VER%" == "6" netsh advfirewall firewall set rule  group="ファイルとプリンターの共有" new enable=yes

rem リモートサービス管理の許可
if "%VER%" == "5" netsh firewall set service REMOTEADMIN enable
if "%VER%" == "6" netsh advfirewall firewall set rule  group="リモート サービス管理" new enable=yes

rem リモートRPCの許可
reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server" /v AllowRemoteRPC /t reg_dword /d 1 /f

rem リモートデスクトップの許可
if "%VER%" == "5" netsh firewall set service REMOTEDESKTOP enable
if "%VER%" == "6" netsh advfirewall firewall set rule  group="リモート デスクトップ" new enable=yes
reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fDenyTSConnections /t reg_dword /d 0 /f

rem ローカルグループの構成
set DC=%LOGONSERVER:~1%
net localgroup administrators "%USERDOMAIN%\%RD-VH%$" /add
net localgroup "Remote Desktop Users" "%USERDOMAIN%\Domain Users" /add
net localgroup "Remote Desktop Users" "%USERDOMAIN%\Domain Admins" /add
投稿者 横山哲也 時刻: 16:58
ラベル: ,

2 件のコメント:

  1. 匿名2011年11月22日 21:51

    昨日は研修でお世話になりました。受講生です。
    知りたいことを細かく教えてもらうことが出来て、とても充実した研修でした。
    その中で、スクリプトをデータで欲しいというわがままにもこのようにご対応いただき、感謝の限りです。
    遠慮なくいただいていきます。
    また何かの機会がありましたら、よろしくお願いします。

    返信削除
  2. 横山哲也2011年11月22日 21:58

    ご受講ありがとうございました。
    参考になれば幸いです。
    込み入った話は、会員ページからご質問いただければ、可能な範囲でお答えします。
    よろしくお願いします。

    返信削除

登録: コメントの投稿 (Atom)